Aliasse und Scripting in mIRC

on ^*:JOIN:*:{ 
  ; wenn ich einen Channel betrete: Alle Namen auflisten lassen, für das log
  if ($nick == $me) { 
    set $($+(%,$network,.,$cid,.log_names,.,$chan),1) true
    ; /names $chan    ; unnötig, da mIRC dies bereits einmal macht, und das reicht
  }
}

raw 366:*: {
  if ( $($+(%,$network,.,$cid,.log_names,.,$2),2) == true ) {
    unset $($+(%,$network,.,$cid,.log_names,.,$2),1)
    var %i = 1,%users | while ($nick($2,%i)) { %users = %users $v1 | inc %i }
    echo -t $2 Users on $2: %users
    halt
  }
}

[06:59] * Now talking in #Zefiro
[06:59] Users on #Zefiro: @Zefiro @FurBot
[06:59] <Zefiro> *schnurr*

/inv {
  if ($network == FurNet) {
    if ($1 $+ _ != _) { 
      /invite $1 #Zefiro
    } 
    elseif ( $query($active) ) {
      /invite $active #Zefiro
    } 
  }
}
/invnot /invite $($+(%,$network,.,$cid,.lastnotifyon),2) #Zefiro

on *:NOTIFY: {
    set $($+(%,$network,.,$cid,.lastnotifyon),1) $nick
  }
}

/msg BotServ act #Zefiro stellt sich vor
/msg BotServ say #Zefiro Ich bin der bot

/bsay /raw -q PRIVMSG BotServ :say $$chan $$1-
/bact /raw -q PRIVMSG BotServ :act $$chan $$1-

Alias
/nick {
  ; Debug-Ausgabe
  ;  .echo Wunschnick geändert von $($+(%,$network,.,$cid,.lastnick),2) auf $1
  ; Nick und alternativen Nick setzen (für einen sinnvollen Ersatz bei Disconnect)
  ; wichtig: anick ändert evtl. den Nick, daher nick hinter anick setzen
  ; wichtiger: dieses Ändern ist superlästig, da alle das mitkriegen! Bessere Lösung finden!!
  ;.!anick $($+(%,$network,.,$cid,.lastnick),2) $+ _
  /!nick $1
  ; Nick als gewünschten Nick merken
  set $($+(%,$network,.,$cid,.lastnick),1) $1
  ; awayinfo löschen (meist nach /afk)
  if ($($+(%,$network,.,$cid,.lastaway),2) $+ _ != _) { 
    /away
  }
}

Variables (werden automatisch angelegt)
; Status für die Nickwiederherstellung nach einem Disconnect
; 0 - normal / inaktiv
; 1 - Reconnect brachte anderen Nick, Umbenennen wird versucht (setzt OnConnect)
; 2 - Nick schon vorhanden, GHOST wird versucht (setzt RAW 433 = Nick Exists)
;%notifynickchange 0

; der letzte von uns aktiv gewählte Nick, wird nach Disconnect als Reconnectnick verwendet
;%lastnick Zefiro

; das Passwort für Nickserv für meine registrierten Nicks
%config.FurNet.nickservpwd password

Remote
on *:START: {
  ; den Nick zurückstellen, wenn er vom letztenmal noch anders war
  ; (optional, und wenig tauglich im Multi-netz-Betrieb)
  ;/nick Zefiro
}

on *:DISCONNECT: {
  ; Informative (Debugging) Ausgabe, erscheint direkt nach dem Disconnect (auch wenn Usergewollt)
  echo last wanted nick was: $($+(%,$network,.,$cid,.lastnick),2) (actual nick was $me $+ )
  ; Letzten Nick merken - redundant, da wir /nick ja auch abfangen
  ; hiermit kriegen wir serverseitiges Umbenennen mit - wollen wir dies denn als neuen Wunschnick?
  ; Ausnahme: wenn wir gerade versuchen, uns umzubenennen - dann %lastnick unverändert lassen
  if ($($+(%,$network,.,$cid,.notifynickchange),2) == 0) {
    set $($+(%,$network,.,$cid,.lastnick),1) $me
  }
  ; wenn wir grade dabei waren, uns umzubenennen - notify löschen
  if ($($+(%,$network,.,$cid,.notifynickchange),2) == 2) {
    /!notify -r $($+(%,$network,.,$cid,.lastnick),2)
  }
}

on *:CONNECT: {
  ; wir wollen nicht invisible sein - selbst wenn +i serverdefault ist
  /mode $me -i
  ; sind wir, wer wir sein wollen?
  if ($me != $($+(%,$network,.,$cid,.lastnick),2)) {
    set $($+(%,$network,.,$cid,.notifynickchange),1) 1
    /!anick $($+(%,$network,.,$cid,.lastnick),2) $+ _
    /!nick $($+(%,$network,.,$cid,.lastnick),2)
  }
  ; wenn noch ein away gesetzt war, neu setzen
  if ($($+(%,$network,.,$cid,.lastaway),2) $+ _ != _) { 
    /away $($+(%,$network,.,$cid,.lastaway),2)
  }
}

on *:NOTIFY: {
  ; Reconnect-Notify wegfiltern
  if ($nick == $($+(%,$network,.,$cid,.lastnick),2)) {
    halt
  } 
  else {
    ; für /invnot
    set $($+(%,$network,.,$cid,.lastnotifyon),1) $nick
  }
}

on *:UNOTIFY: {
  if ($nick == $($+(%,$network,.,$cid,.lastnick),2) && $($+(%,$network,.,$cid,.notifynickchange),2) == 2) {
    unset $($+(%,$network,.,$cid,.notifynickchange),1)
    /!nick $($+(%,$network,.,$cid,.lastnick),2)
    /!notify -r $($+(%,$network,.,$cid,.lastnick),2)
    halt
  }
}

raw 433:*: { ; Nick schon vergeben
  if ($1 == *) {
    echo Nick exists: $1- (was: $($+(%,$network,.,$cid,.lastnick),2))
  } 
  else if ($($+(%,$network,.,$cid,.notifynickchange),2) == 1) {
    set $($+(%,$network,.,$cid,.notifynickchange),1) 2
    /!notify $($+(%,$network,.,$cid,.lastnick),2)
    ; GHOSTen - vielleicht hilft's ja... (sofern der aktuelle Nick erkannt ist und der neue mir auch gehört)
    if ($($+(%,config.,$network,.nickservpwd),2) $+ _ != _) {
      /raw -q PRIVMSG nickserv : $+ ghost $($+(%,$network,.,$cid,.lastnick),2) $($+(%,config.,$network,.nickservpwd),2)
    }
    halt
  } 
  else { ; Nickchange wurde manuell angestossen
    ; alter Nick ist weiterhin 'gewünschter' Nick bzgl. Autorename (/nick ändert .lastnick)
    set $($+(%,$network,.,$cid,.lastnick),1) $1
  }
}

; ein Ghost-Kommando meldete, daß der Nick nicht in Verwendung sei
; kam das von uns? $2 ist der Nick
On ^*:NOTICE:Nick*isn't currently in use.:*: {
  ; NickServ gibt den Nick in Fettschrift zurück, daher mit den entsprechenden Steuerzeichen vergleichen
  if ($2 ==  $+ $($+(%,$network,.,$cid,.lastnick),2) $+  && $($+(%,$network,.,$cid,.notifynickchange),2) == 2) {
    /!echo NickServ says, $($+(%,$network,.,$cid,.lastnick),2) is available - renaming
    unset $($+(%,$network,.,$cid,.notifynickchange),1)
    /!nick $($+(%,$network,.,$cid,.lastnick),2)
    /!notify -r $($+(%,$network,.,$cid,.lastnick),2)
    haltdef
  }
}

Alias
; meine häufig verwendeten Nicks
/zef /nick Zefiro
/zzz /nick zZzZefiro
/work /nick Zefi_Work
/afk {
  ; Nick setzen
  /nick Zefi_AFK
  ; danach(!) away setzen
  if ($1 $+ _ != _) { 
    set $($+(%,$network,.,$cid,.lastaway),1) $1-
    /away $($+(%,$network,.,$cid,.lastaway),2)
  }
}

/away {
  set $($+(%,$network,.,$cid,.lastaway),1) $1-
  /!away $1-
}

/nick {
  ; awayinfo löschen (meist nach /afk)
  if (%lastaway $+ "_" != "_") { 
    /away
  }
}

Variables
; das Passwort für Nickserv für meine registrierten Nicks
%config.FurNet.nickservpwd xxxxxxxx
%config.freenode.nickservpwd xxxxxxxx

Remote
On ^*:NOTICE:This nickname is registered and protected*:*: {
  if ($($+(%,config.,$network,.nickservpwd),2) $+ _ != _ && $nick == nickserv) {
    /raw -q PRIVMSG nickserv : $+ identify $($+(%,config.,$network,.nickservpwd),2)
  }
}

On ^*:NOTICE:This nickname is owned by someone else*:*: {
  if ($($+(%,config.,$network,.nickservpwd),2) $+ _ != _ && $nick == nickserv) {
    /raw -q PRIVMSG nickserv : $+ identify $($+(%,config.,$network,.nickservpwd),2)
  }
}

Alias
/whois !whois $$1 $$1